《魔兽世界怀旧服》圣骑士一键宏

许多玩家在魔兽世界怀旧服中是不是觉得操作比较繁琐呢？特别是奶这种角色要处理的事情非常的多，很多时候都按不来，不过官方也是在游戏内置了宏的设置，接下来小编就带来了一些圣骑士的一键宏推荐。

魔兽世界怀旧服圣骑士一键宏推荐

1.[祝福]点击或键盘按击为目标施放强效智慧祝福，为智慧祝福。点击或键盘按击为目标施放强效力量祝福，为力量祝福。<鼠标左键>点击或键盘按键为目标施放强效王者祝福，<鼠标右键>为王者祝福。

#showtooltip

/cast [mod:ctrl,button:1]强效智慧祝福

/cast [mod:ctrl,button:2]智慧祝福

/cast [mod:shift,button:1]强效力量祝福

/cast [mod:shift,button:2]力量祝福

/cast [button:1]强效王者祝福

/cast [button:2]王者祝福

== 圣骑士日常祝福还有光明和拯救，游戏专用鼠标还有键位的可以继续加入绑定(只要不超过255个字符即可)。这里辅助控制键还有Alt键，因为自我施法的默认快捷键就是Alt键。大家又习惯默认开启自动自我施法，为避免冲突，所以本宏没有加入。有意的可自行加入。

== 这是一种利用组合键施放法术的宏。优点是把众多BUFF集合到一个图标，可自己根据情况为目标施放不同的大小BUFF。缺点是需提前选定要施放BUFF的目标。在团本或野外通常我们都是鼠标点选目标，此宏还需要鼠标挪回图标位置施放，比较繁琐低效。处于5人小队时，可以左手按键F1到F5选择队友，再配合此宏能稍快捷些。

可以把此宏按不同祝福分解为多个宏。例如：

2.[王者]点击直接施放强效王者祝福，按住Ctrl键则施放王者祝福

#showtooltip [mod:ctrl]王者祝福;强效王者祝福

/cast [mod:ctrl,help,nodead]王者祝福;[help,nodead]强效王者祝福

提高点效率，这回加入鼠标指向：

3.[王者]点击向鼠标指向非死亡友好目标施放强效祝福，无鼠标指向则为当前所选非死亡友好目标施放强效祝福，鼠标指向、选定目标为非友好目标或无时则对自己施放强效王者祝福。同等情况按住Ctrl键则施放普通王者祝福

#showtooltip 强效王者祝福

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead][mod:ctrl]王者祝福;[@mouseover,help,nodead][help,nodead][]强效王者祝福

还能再提高效率吗？看看下面这个：

4.[王者]鼠标指向为团队队友则施放强效祝福，鼠标指向为非队友友好目标则施放普通祝福，无鼠标指向则为当前所选非死亡友好目标施放普通祝福，无任何目标或鼠标指向自己则对自己施放普通祝福，无论何种情况按住Alt键为自己施放强效祝福。

#showtooltip 强效王者祝福

/cast [mod:alt,@player][@mouseover,group,help,nodead]强效王者祝福;[@mouseover,help,nogroup:party,nodead][]王者祝福

说明:众所周知，骑士的普通祝福可以对友好玩家施放，强效祝福只能为团队中的队友施放，所以本宏利用此点将两者合二为一。同时还加入了鼠标指向，令操作更加的便捷。

建议依此为模板，将每种祝福做一个宏。

下面展示高度整合的终极祝福宏：

5.[光力智]当鼠标指向为团队队友时只为其施放强效祝福，鼠标指向为非团队队友时为其施放普通祝福。如无鼠标指向或鼠标指向非友好目标时，则直接对当前所选目标施放普通祝福。

#showtooltip

/cast [mod:ctrl,@mouseover,group,help]强效力量祝福;[mod:ctrl,@mouseover,help][mod:ctrl,help]力量祝福;[mod:shift,@mouseover,group,help]强效智慧祝福;[mod:shift,@mouseover,help][mod:shift,help]智慧祝福; [@mouseover,group,help] 强效光明祝福; [@mouseover,help] [help]光明祝福

6.[王拯庇]

#showtooltip

/cast [mod:ctrl,@mouseover,group,help]强效拯救祝福;[mod:ctrl,help]拯救祝福;[mod:shift,@mouseover,group,help]强效庇护祝福;[mod:shift,@mouseover,help][mod:shift,help]庇护祝福; [@mouseover,group,help] 强效光明祝福;[mod:alt,@player] [@mouseover,help] [help]王者祝福

缺点：只加入了按住Alt键为自己加强效王者，鼠标指向自己或选定自己才能为自己施放普通祝福。不能利用Alt键，选定友好目标时强制为自己施放其他祝福。还有就是没有队伍时，无法为自己加其它强效祝福。

*提示：[]里边是为此宏起的名称，当宏图标放入动作条时，只能显示出名称的前2个汉字或4个英文字母。所以为宏起个简洁的名称可以起到准确提示的作用。

== 还需要注意的是这种绑定了Ctrl、Shift、Alt等组合键不要和游戏默认按键冲突，否则宏无法执行。例如： 是第一个宏物技能，为第一个动作条。把此宏放在1键上则无法正常执行。

网上能搜到根据职业判断加力量还是智慧的脚本，在这里我就不放出来了。以上不同的宏适合不同的情况和风格，具体喜欢哪个自己选择。我个人推荐第四个。

教学：#showtooltip非常好用的图标显示及提示命令，和“?”配合使用。

[mod:ctrl/shift/alt]指认辅助键

[button:1/2/...]指认按键。1为鼠标左键或键盘按击，2为鼠标右键。多按键鼠标还可以往后绑定。

[@mouseover] 鼠标指向

[group]团队队友

[help]友好目标(这里省略了一句exists 判断目标存在的意思，指认友好目标就确定存在了)

/cast施放技能命令 中文格式为 /施放

7.[正义]释放正义圣印的同时，开始近战攻击。网上最常见的宏

#showtooltip 正义圣印

/startattack

/cast 正义圣印

优点：节省近战攻击按键及操作，同时避免误操作停止近战攻击

缺点：万一遇到需要近战停手时，只能远离近战攻击范围，或转身、或清除当前目标。

适用：正义圣印适合单手快速武器打伤害，通常为小号出命令圣印前升级打怪使用。还有一个好处就是学习高等级技能免除拖动替换。

== 根据不同场合需要可更改为其他圣印。小号使用慢速双手武器或练习升级武器技能，挂十字军圣印。惩戒骑挂命令圣印。比如消耗战或血量有压力时，挂光明圣印近战砍怪回血。奶骑在团本中，蓝已耗尽或治疗无压力时，通常挂着智慧圣印去近战砍怪回蓝。

拓展：在 /cast 命令圣印 此行之上加一行 /cast 审判 因为审判不占用GCD，所以可审判同时挂圣印。(惩戒骑常用，绑命令圣印，审判同时挂命令圣印平砍，DPS最大化)

教学：/startattack为开始近战攻击 与系统自带的攻击按键不同是，再按一次也不会停止攻击。/stopattack为停止近战攻击。

也可以把多个圣印整合到一起：

8.[圣印]默认命令圣印，按住Ctrl为十字军圣印，Ctrl+鼠标右键为正义圣印，按住Shift为智慧圣印，Shift+鼠标右键为光明圣印，按住Alt为1级命令圣印，按住Alt+鼠标右键为公正圣印。<本人使用的宏>

#showtooltip

/startattack

/cast [mod:ctrl,button:1]十字军圣印

/cast [mod:ctrl,button:2]正义圣印

/cast [mod:shift,button:1]智慧圣印

/cast [mod:shift,button:2]光明圣印

/cast [mod:alt,button:1]命令圣印(等级 1)

/cast [mod:alt,button:2]公正圣印

/cast 命令圣印

说明：一个图标整合所有圣印。喜欢的自己可以根据使用情况调换圣印位置。

优点：多个圣印绑定在一个键位，且圣印蓝够就能用，不用考虑CD冷却的问题。

拓展：也适用于骑士的光环甚至生活专业技能(比如锻造、工程和采集等)。把 /startattack去掉，更改技能名称即可。

9.[上马]非战斗中则召唤千金马，战斗中则释放审判。<本人使用的宏>

#showtooltip [nocombat]召唤战马(召唤);[combat]审判

/cast [nocombat]召唤战马(召唤);[combat]审判

说明：没有加入下马/dismount是因为安装了自动起立、下马插件。否则好多宏都要加入比较繁琐。

优点：节省一个键位，且审判和上马都是高频率使用技能，放在同一个高频键位方便快捷高效(本人放在4键)。

缺点：无法主动审判起手进入战斗(此种情况极少，所以本宏很实用)。

适用：日常及PVE。

拓展：PVP需审判起手可将审判前[combat]删除。需注意挂有圣印时，当前所选目标不要为被动敌对目标(黄名怪)或中立目标，或以上目标不在审判的10码范围内。否则容易意外审判进入战斗。

== 还有部分人弄了熊怪变身，需取消变身才能上马，则在上面加一行/cancelaura 熊怪形态

== PVE中还可以在审判上一行加入一行 /startattack即开始近战攻击。需要再注意一点：上马时，面前近战范围内不能有被动敌对目标(黄名怪)或中立目标。否则容易意外砍怪进入战斗。

== 也可以将上马和其他不常用的技能绑定在一个宏内，将审判替换为该技能名即可。比如十字军、公正圣印等。上马也可以和其它对敌对目标施放又不常用的技能组合绑定，比如驱邪术，愤怒之锤，制裁等(但野外情况复杂，有时需要驱邪开怪，遇到敌对很可能要制裁起手或愤怒收割。而审判不好和其它技能绑定，所以最终考虑将两者合并)。不推荐绑定增益技能是因为脱战后很可能和日常操作冲突。(比如脱战后需要治疗，驱散或救人加BUFF)。在此鄙视一下每回上下马还喊话的人。/玩笑

== 有些人会选择把跑路神器棍子上的胡萝卜也加入到宏里，加入一句/equipslot [mounted] 13 石楠之环;[nomounted]13 棍子上的胡萝卜即可(唯一麻烦就是下马也需要按下此宏将饰品按回来。也可以利用饰品管理插件实现。还有追求极速的想把驸魔骑乘的手套还有加装马刺的靴子也换上。换饰品和装备用宏都能实现(下面给大家贴出来)，就是更换装备需改动宏有点繁琐，利用一键换装插件再绑定个快捷键会比较简便快捷。

教学：[combat]判断为战斗状态中 [nocombat]非战斗状态中，即脱战。

10.[跑马]每行前面的是输出装备，后面的是加速装备

#showtooltip 召唤战马(召唤)

/equipslot [mounted] 13 石楠之环;[nomounted] 13 棍子上的胡萝卜

/equip [mounted] 输出手套名称;[nomounted] 加速手套名称

/equip [mounted] 输出靴子名称;[nomounted] 加速靴子名称

/cast [nocombat]召唤战马(召唤)

/dismount [mounted]

教学：/equipslot将装备在指定位置 13，14依次为第一，第二饰品位

/equip直接装备

[mouted]判断为骑行状态中

11.[救锤]当非战斗状态时，对鼠标指向已死亡友好目标施放救赎，无鼠标指向则直接对当前所选死亡友好目标救赎，或施放救赎后点选尸体复活。如鼠标指向为敌对目标时则对其施放愤怒之锤，无鼠标指向直接向当前敌对目标施放愤怒之锤。<本人使用的宏>

#showtooltip [help]救赎;[harm]愤怒之锤

/cast [@mouseover,help,dead,nocombat][help,dead,nocombat] [@none,nocombat] 救赎;[@mouseover,harm,nodead][harm,nodead]愤怒之锤

说明：日常脱战救人和斩杀不冲突，所以绑定在一起节省一个键位及图标。其实救人本来就是脱战才能对死亡友好目标使用，不需要加入[help,dead,nocombat]判断命令,还有愤怒之锤中的[harm,nodead]都不影响宏的执行。加入是为了避免操作时语音提示：我还无法使用这个法术。如果编写宏的字数过多超出255字符限制，可将其去除。

优点：将救人和收割绑定到一起，还加入了鼠标指向。

拓展：因救赎需要非战斗状态下对死亡友好目标使用，所以可以和其他对存活敌对目标施放的技能组合在一起，比如制裁之锤，驱邪术等。(通常脱战后，其他对存活友好目标施放的技能比如清洁术，祝福，治疗等等，此类操作和救人容易冲突，所以不推荐绑定在一起。)也可以加入救人喊话使用。

教学：[harm]目标敌对，绝大多数情况也可用[nohelp]表示

[dead]目标死亡 同理[nodead]表示目标存活

[@none] 目标为无 有时队友死亡已释放尸体，需要先按救赎再用鼠标点击尸体。宏里用此命令才能实现。

12.[清邪]当鼠标指向为存活友好目标时对其施放清洁术，无鼠标指向时对所选友好目标施放清洁术，无目标时对自己施放清洁术。也可按住ALT键无论目标为何强行自我清洁。当鼠标指向为敌对目标时对其施放驱邪术，无鼠标指向直接向当前敌对目标施放驱邪术。<本人使用的宏>

#showtooltip [help]清洁术;[harm]驱邪术

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][]清洁术;[@mouseover,harm,nodead][harm,nodead]驱邪术

说明：因驱邪术只能对亡灵及恶魔目标使用，适用情况较少。所以和清洁术绑定在一起。

优点：节省一个键位，放在同一个高频键位方便快捷高效。

缺点：当身上有DEBUFF需要驱散，且敌对为亡灵或恶魔目标时。只能先驱散，再输出。(目标为亡灵或恶魔的情况较少，而恶魔亡灵放毒的时候也较少，所以本宏比较实用)若在意此点，也可将清洁术前的[]删掉。但需目标为自己或按Alt键才能为自己驱散。自行取舍吧。

教学：@player代表指定目标为玩家自己

13.[圣光]鼠标指向非死亡友好目标时对其治疗，无鼠标指向时对所选非死亡友好目标治疗，无鼠标指向且当前目标为敌对时为其目标(我方友好)治疗，无鼠标指向也无当前目标时对自己治疗(需开启自动自我施法)。也可按住Alt键无论目标为何强行自我治疗。

#showtooltip 圣光术

/StopCasting

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][@targettarget,help,nodead][]圣光术

说明：这里需要讲解一下操作，加入鼠标指向治疗可以应对绝大多数情况。我用奶骑团本都是选定主T为目标，当主T血量稳定的时候，利用鼠标指向为其他人治疗。当遇到某些BOSS需要不停换T的时候就很繁琐，需要显示目标的目标的目标(主T--BOSS--当前T)，然后鼠标时刻准备对准他治疗。这时可以把当前目标换成BOSS，这样直接治疗目标的目标(BOSS---当前T)。

还加入了打断施法，可以快速打断读条再重新治疗。适合根据BOSS技能反复预读治疗。

优点：方便快捷团本治疗，节省鼠标点选队友时间。灵活应对各种环境状况。

缺点：默认只能使用最大等级圣光术，不能选择技能等级。

适用：最适合群体PVP，也适合日常PVE。

拓展：此宏也适用于圣光闪现或神圣震击还有清洁术，更改技能名称即可。也可以利用组合键，将其整合到一起。例如：

14.

/StopCasting

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead][mod:ctrl,@targettarget,help,nodead][mod:ctrl]圣光闪现;[mod:shift,@mouseover,help,nodead][mod:shift,help,nodead][mod:shift]神圣震击;[@mouseover,help,nodead][help,nodead][@targettarget,help,nodead][]圣光术

教学:target 目标

targettarget 目标的目标

15.[神震]神恩+神圣震击 可鼠标指向。

#showtooltip 神恩术

/StopCasting

/cast 神恩术

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead][]神圣震击

说明：因为神恩术不占GCD，所以可和治疗技能绑定同时施放。两个技能冷却时间不能全在图标处直观显示，需搭配WA等技能冷却插件配合使用。

适用：重要队友危急抬血用。奶骑团本必备

16.[多圣]效果同上边的圣光宏，不同是此宏加入可选择预告设置好的技能等级施放。默认为顶级圣光，按ctrl键为4级圣光，按shift键为7级圣光。<本人使用的宏>

#showtooltip 圣光术

/StopCasting

/cast [mod:ctrl,@mouseover,help][mod:ctrl,help][mod:ctrl,@targettarget,help,nodead][mod:ctrl]圣光术(等级 4);[mod:shift,@mouseover,help][mod:shift,help][mod:shift,@targettarget,help,nodead][mod:shift]圣光术(等级 7);[mod:alt,@player] [@mouseover,help] [help][@targettarget,help,nodead][]圣光术

优点：方便快捷团本治疗，节省鼠标点选队友时间。还增加了不同等级的治疗术，灵活应对各种环境状况。我正在使用的宏。将其放置在鼠标滚轮，配合左手按组合键，快速反应不影响走位

缺点：只能用Alt键强行用顶级圣光术自我治疗。

适用：尤其适合团本及日常PVE

拓展：也适用于圣光闪现，更换技能名称和等级即可。

17.[圣疗]立即停止当前施法，当鼠标指向为存活友好目标时对其施放圣疗术，无鼠标指向时直接对所选存活友好目标施放圣疗术。按住ALT键则无视任何目标对自己施放圣疗术。

#showtooltip 圣疗术

/StopCasting

/cast [mod:alt,@player][@mouseover,help,nodead][help,nodead]圣疗术

说明：为了最快速的反应，在施放圣疗术之前加入了/StopCasting暂停当前施法。不加入的话，经常是正在圣光读条，发现MT瞬间血丝到底，必须先移动一下停止当前施法才能施放圣疗。

还有一种情况是正要圣疗时队友暴毙，开启了自动自我施法的时候，圣疗直接给了自己。不仅浪费CD非常长的救命技能，还会仅剩少量的蓝。

优点：最快速圣疗队友，且不会因队友暴毙而误将圣疗加给自己。

缺点：当遇到血量不足需对自己施放时，需将鼠标指向自己，或点选自己，或按Alt键。(若在意此点，可在圣疗术前加[]，但如此就失去了此宏前面的优点)。

适用：团本PVE。很明显不适用于插旗单P

拓展：也适用于保护祝福，自由祝福，更换技能名称即可。可以加入喊话。也可以利用组合键，将其整合到一起:

18.[保圣自]立即停止当前施法，当鼠标指向为存活友好目标时对其施放保护，无鼠标指向时直接对存活所选友好目标施放保护。鼠标指向及所选目标为敌对目标或无时对自己施放保护。按住Ctrl键则施放圣疗，按住Shift键则为自由。<本人使用的宏>

#showtooltip

/StopCasting

/cast [mod:ctrl,@mouseover,help,nodead][mod:ctrl,help,nodead]圣疗术;[mod:shift,@mouseover,help,nodead][mod:shift,help,nodead][mod:shift]自由祝福;[@mouseover,group,help,nodead][group,help,nodead]保护祝福

说明：圣疗术、保护和上一个宏一样选择不能默认自我施放，需鼠标指向或选择自己(需要的话圣疗术前面加[mod:ctrl],保护前面加[])。自由可以，但需要鼠标指向、所选目标为非友好目标或无目标或目标为自己。

哪个技能需要按Alt键强制自我施法可以在技能前加一条[mod:alt,@player]

优点：多个技能绑定一起，鼠标指向快速反应。

缺点：图标不直观，需一段时间熟悉。技能冷却时间不能全在图标处直观显示，需搭配WA等技能冷却插件配合使用。

教学：在这里强调一下[help,nodead][]和[help,nodead]还有[]的区别。[]里边没有指认目标，包括当前目标或无目标多种情况。所以[help,nodead][]也可以简化为[]。而[help,nodead]则指认当前目标，所以圣疗术才得以失去目标也不会施放在玩家自己身上。

19.[制裁]立即停止当前施法，当鼠标指向为敌对目标时对其制裁，无鼠标指向直接向当前敌对目标制裁。<本人使用的宏>

#showtooltip 制裁之锤

/StopCasting

/cast [@mouseover,harm,nodead][harm,nodead]制裁之锤

适用：群体PVP 小队PVE

拓展：也适用于惩戒骑的忏悔。也可以利用组合键，将其整合到一起。

20.[奉献]立即停止当前施法，施放奉献。按住alt则施放1级奉献。网上最常见的宏。<本人使用的宏>

#showtooltip 奉献

/StopCasting

/cast [mod:alt]奉献(等级 1);奉献

说明：这里的辅助按键可以设置为Ctrl或Shift。因为自我施法快捷键默认为Alt键，所以其他可以对自己施放的增益法术(比如祝福、治疗、驱散)都绑定为其他键，而这类只能对敌对目标生效的技能辅助都设置为Alt键以做区分。

适用：多用于骑士单刷副本控蓝，更多时候适用于和贼PVP。这里就不得不提到一个网上常见的骑士抓贼宏：

21.[抓贼]自动锁定10码之内的敌对目标，如果身上有圣印则直接对其审判。

/targetenemy

/script SetCVar("targetNearestDistance",10)

/cast 审判

说明：没有办法，骑士是出了名的手短脚短。10码已经是最远的审判距离了，所以只能限制锁定范围。

适用：没错，也许你们也想到了。这个宏再加上面的奉献宏也可用于争抢刷新的任务怪。所以我一个PVP菜鸟才敢放出来。(想当初怀旧开服，人比怪多。本人就是靠此宏抢怪才得以逃脱人山人海)

22.[余蓝]只有在有队伍时，喝水并说出当前蓝量百分比。如需没有队伍也可通报，可将 /stopmacro [nogroup:party] 此行删掉。此宏是网上借用的。

#showtooltip

/use 魔法晶水

/use 魔法甜面包

/use 晨露酒

/use 魔法苏打水

/stopmacro [nogroup:party]

/run c=string.format("%d", UnitPower("player")/ UnitPowerMax("player")*100) SendChatMessage(c.."% 的法力剩余", "say",nil, 1)

23.[余血]只有在有队伍时，吃面包并在队伍中说出当前血量百分比。如需没有队伍也可通报，可将 /stopmacro [nogroup:party] 此行删掉。此宏是网上借用的。

#showtooltip

/use 嫩狼肉排

/use 魔法甜面包

/use 奥特兰克魔法点心

/stopmacro [nogroup:party]

/run c=string.format("%d", UnitHealth("player")/ UnitHealthMax("player")*100) SendChatMessage(c.."% 面包回血中……", "party",nil, 1)

24.[标记]图标编号 0=取消图标;1=黄色四角星;2=橙色圆形;3=紫色菱形;4=绿色三角;5=白色月亮;6=蓝色方块;7=红色叉子;8=骷髅

/script SetRaidTarget("target",图标编号);

*说明：可以自己根据情况将标记宏加入到技能里。比如忏悔加个星星，制裁加个菱形，审判加个骷髅。适合5人10人小队使用。

初次使用/script命令会有安全警告，忽略即可，绝对安全。

再分享一些比较实用的命令：

[聊天窗口显示职业颜色]0显示/1不显示 /console SET chatClassColorOverride "0" 根据聊天判断职业，方便加BUFF

[死亡灰色特效]0关闭/1开启 /console ffxDeath 0 死亡释放以后会有灰色特效，阴森恐怖死气沉沉。关闭以后一切又恢复五彩缤纷、生机勃勃。

[重置副本] /run ResetInstances() 刷副本常用命令，再加入喊话，方便快捷。

[隐藏动作条两边狮鹫] 左/右 /script MainMenuBarLeftEndCap:Hide() /script MainMenuBarRightEndCap:Hide()

[最大镜头距离]1-2.6 /console CameraDistanceMaxZoomFactor 2.6

[改TAB距离]身前/身后 0-50码 /console SET targetNearestDistance "50" /console SET targetNearestDistanceRadius "50"

小编推荐：

>>>《魔兽世界怀旧服》各职业宏大全

最新资讯
团本纳克萨玛斯任务大全	NAXX攻略专区	纳克萨玛斯首领攻略大全	纳克萨玛斯物品掉落大全
热门资讯
纳克萨玛斯法师毕业装备参考	纳克萨玛斯狂怒战毕业装备参考	纳克萨玛斯防战毕业装备参考	纳克萨玛斯剑专精贼毕业装备参考
纳克萨玛斯匕首专精贼毕业装备参考	盗贼开锁技能1-300升级攻略	碎裂白骨战斧属性简介	帝殒属性简介
蛛魔制奴者属性简介	萨菲隆的精华属性简介	NAXX克尔苏加德故事背景	NAXX大领主莫格莱尼故事背景